subroutine bremliqo(dens,t,gamma,qbremlo)
*
* This subroutine returns the bremsstrahlung neutrino rates computed for 
* Liquid Oxygen using the results of Itoh, Kohyama, Matsumoto, & Seki 
* 1984, ApJ, 280, 787 and Itoh & Kohyama 1983, ApJ, 275, 858
* These formulae include liquid metal and low temp. quantum correction conts.
*
      implicit double precision (a-z)
*
*  declare variables (find the values in the block data piece of code).
*
      common/liqdato/ a(6), b(4), e(6), f(4), i(6), j(4), p(6), q(4),
     1          alpha(4), beta(4), c, d, g, h, k, l, r, s
      common/quandato/ aq(6), bq(4), eq(6), fq(4),
     1          alphaq(5), cq, dq, gq, hq

      at = 16.
      z = 8.
      twopi = 6.283185308
      pisqr = 9.869604404
      en = 2.
      s2theta = 0.217
      cv = 0.5 + 2.*s2theta
      ca = 0.5
      cvp = 1. - cv
      cap = 1. - ca
      x13 = -1./3.
      xone3 = 1./3.
      x14 = -0.25000000
      x23 = -2./3.
      x24 = -0.50000000
      x34 = -0.75000000
      x43 = 4./3.
      t8 = 10.**t / 1.e+08
      d6 = 10.**dens / 1.e+06 
      alfa = 0.07279 * gamma * (d6**xone3) / ((z*at)**x43)
*
* compute the interpolation coefficients v and w.
* NOTE: u is defined differently here than in BREMSOL*.f
*
      u = twopi * ( dens - 3. ) / 10.
*
* liquid variables
*
      v = alpha(1) + alpha(2) * gamma**x13 + alpha(3) * gamma**x23
     1    + alpha(4) / gamma
      w = beta(1) + beta(2) * gamma**x13 + beta(3) * gamma**x23
     1    + beta(4) / gamma
*
* quantum correction variables
*
      vq = alphaq(1) + alphaq(2)*gamma**x14 + alphaq(3)*gamma**x24
     1    + alphaq(4)*gamma**x34 + alphaq(5) / gamma
*
* set up the variables (sines and cosines) for the loops
*
      su  = dsin(u)
      su2 = su * su 
      cu2 = 1. - su2
      cu  = dsqrt( cu2 )
      s2u = 2. * su * cu
      c2u = cu2 - su2
      s3u = su * ( 3. - 4. * su2 )
      c3u = cu * ( 4. * cu2 - 3. )
      c4u = -8. * cu2 * su2 + 1.
      s4u = su * ( (2.*c3u) + (2.*cu) )
      c5u = cu * ( (16.*cu2*cu2) - (20.*cu2) + 5. )
*
*  Liquid contributions
*
      asum = a(1) + a(2) * cu + a(3) * c2u
     1            + a(4) * c3u + a(5) * c4u + a(6) * c5u
      bsum = b(1) * su + b(2) * s2u + b(3) * s3u
     1       + b(4) * s4u + c*u + d
      esum = e(1) + e(2) * cu + e(3) * c2u
     1            + e(4) * c3u + e(5) * c4u + e(6) * c5u
      fsum = f(1) * su + f(2) * s2u + f(3) * s3u
     1       + f(4) * s4u + g*u + h
      isum = i(1) + i(2) * cu + i(3) * c2u
     1            + i(4) * c3u + i(5) * c4u + i(6) * c5u
      jsum = j(1) * su + j(2) * s2u + j(3) * s3u
     1       + j(4) * s4u + k*u + l
      psum = p(1) + p(2) * cu + p(3) * c2u
     1            + p(4) * c3u + p(5) * c4u + p(6) * c5u
      qsum = q(1) * su + q(2) * s2u + q(3) * s3u
     1       + q(4) * s4u + r*u + s
*
* Quantum correction contributions
*
      aqsum = aq(1) + aq(2) * cu + aq(3) * c2u
     1       + aq(4) * c3u + aq(5) * c4u + aq(6) * c5u
      bqsum = bq(1) * su + bq(2) * s2u + bq(3) * s3u
     1       + bq(4) * s4u + cq*u + dq
      eqsum = eq(1) + eq(2) * cu    + eq(3) * c2u
     1       + eq(4) * c3u + eq(5) * c4u + eq(6) * c5u
      fqsum = fq(1) * su + fq(2) * s2u + fq(3) * s3u
     1       + fq(4) * s4u + gq*u + hq
*
* sum up Liquid contributions
*
      fliq1 = asum + bsum
      fliq160  = esum + fsum
      gliq1 = isum + jsum
      gliq160  = psum + qsum

      fliq    = v * fliq1 + (1. - v) * fliq160
      gliq    = w * gliq1 + (1. - w) * gliq160
*
* sum up Quantum correction contributions
*
      rquan1 = aqsum + bqsum
      rquan160 = eqsum + fqsum

      delfof = (1. - vq)*rquan1 + vq * rquan160
      delgog = (1. - vq)*rquan1 + vq * rquan160
*
* sum up for total neutrino loss contributions in liquid phase
*
      ftot = (1. - alfa * delfof) * fliq
      gtot = (1. - alfa * delgog) * gliq
*
* compute neutrino loss rate
*
      first = 0.5*(cv*cv + ca*ca + en*cvp*cvp + en*cap*cap)*ftot
      sec = 0.5*(cv*cv - ca*ca + en*cvp*cvp - en*cap*cap)*gtot
      qbremlo = 0.5738*(z*z/at)*(t8**6)*(first - sec)

      return
      end 

************************************************************************